cultist.club-website/flake.nix

{
  description = "cultist.club landing page";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-25.11";
  };

  outputs = { self, nixpkgs }:
    let
      systems = [
        "x86_64-linux"
        "aarch64-darwin"
      ];
      forAllSystems = nixpkgs.lib.genAttrs systems;
    in
    {
      packages = forAllSystems (system:
        let
          pkgs = import nixpkgs { inherit system; };
          cultist-website = pkgs.buildGoModule {
            pname = "cultist-website";
            version = "0.1.0";
            src = ./.;
            vendorHash = null;
            env.CGO_ENABLED = "0";
            nativeBuildInputs = [ pkgs.makeWrapper ];
            ldflags = [ "-s" "-w" ];
            postInstall =
              let
                linuxWrap = pkgs.lib.optionalString pkgs.stdenv.hostPlatform.isLinux ''
                  wrapProgram $out/bin/cultist-website \
                    --prefix PATH : ${pkgs.lib.makeBinPath [ pkgs.procps ]}
                '';
              in
              ''
                mv $out/bin/website $out/bin/cultist-website
                ${linuxWrap}
              '';
          };
        in
        {
          default = cultist-website;
          cultist-website = cultist-website;
        });

      apps = forAllSystems (system: {
        default = {
          type = "app";
          program = "${self.packages.${system}.default}/bin/cultist-website";
        };
      });

      devShells = forAllSystems (system: {
        default = import nixpkgs { inherit system; }.mkShell {
          packages = [ (import nixpkgs { inherit system; }).go ];
        };
      });
    };
}